Common Issues and Examples/Solutions - Các vấn đề chung và Ví Dụ / Giải pháp

Đây là một bộ sưu tập các ví dụ, giải thích, và câu trả lời cho câu hỏi thường gặp/vấn đề.

The Countdown - Đếm Ngược

Code:

#include <amxmodx>

#define TASKID  1996
#define SECONDS 10

new iSeconds

public plugin_init()
{
    register_plugin( "Countdown Example", "1.0", "Wrecked" )
    
    register_logevent( "LogEventRoundStart", 2, "1=Round_Start" )
}

public LogEventRoundStart()
{
    if( task_exists( TASKID ) )
        remove_task( TASKID )
        
    iSeconds = SECONDS
    set_task( 1.0, "TaskShowCountdown", TASKID, _, _, "a", SECONDS )
}

public TaskShowCountdown()
{
    set_hudmessage( 120, 120, 120, 0.50, 0.50, 0, 0.1, 0.8, 0.1, 0.1, -1 )
    show_hudmessage( 0, "Seconds Remaining: %i", iSeconds-- )
}

Detecting Kill/Headshot Streaks - Phát hiện Kill / Headshot vệt

Code:

#include <amxmodx>

new Headshots[33]
new Kills[33]

public plugin_init()
{
    register_plugin( "How To Keep Kill Counts", "1.0", "Wrecked" )
    
    register_event( "DeathMsg", "EventDeathMsg", "a" )
    
    register_logevent( "LogEventRoundStart", 2, "1=Round_Start" )
}

public EventDeathMsg()
{
    new killer = read_data( 1 )
    new victim = read_data( 2 )
    
    Headshots[victim] = 0
    Kills[victim] = 0
    Kills[killer]++
    
    if( read_data( 3 ) ) // headshot
        Headshots[killer]++
        
    // Kills holds kills of each player
    // Headshots holds headshots
}

public LogEventRoundStart()
{
    arrayset( Headshots, 0, 33 )
    arrayset( Kills, 0, 33 )
}

Once Every x Rounds - Mỗi lần x Rounds

Code:

#include <amxmodx>

#define ROUND_INTERVAL  4

new iRound

public plugin_init()
{
    register_plugin( "Do Something Every X Rounds", "1.0", "Wrecked" )
    
    register_logevent( "LogEventRoundStart", 2, "1=Round_Start" )
}

public LogEventRoundStart()
{
    if( ( ++iRound % ROUND_INTERVAL ) == 1 )
        // do whatever you need to do here
}

Blocking Weapon Pickup - Ngăn chặn vũ khí Pickup

Code:

#include <amxmodx>
#include <hamsandwich>

public plugin_init()
{
    register_plugin( "Block Weapon Pickup", "1.0", "Wrecked" )
    
    RegisterHam( Ham_Touch, "weaponbox", "HamTouchPre", 0 )
    RegisterHam( Ham_Touch, "armoury_entity", "HamTouchPre", 0 )
}

public HamTouchPre( weapon )
    return HAM_SUPERCEDE; // blocks function call 

Properly Removing Buyzones (by Exolent[jNr]) - Loại bỏ đúng cách Buyzones

Code:

#include < amxmodx >
#include < engine >
#include < fakemeta >

new const info_map_parameters[ ] = "info_map_parameters";

new g_hSpawn;

public plugin_precache( ) {
    new iEntity = create_entity( info_map_parameters );
    DispatchKeyValue( iEntity, "buying", "3" );
    DispatchSpawn( iEntity );
    
    g_hSpawn = register_forward( FM_Spawn, "FwdSpawn" );
}

public FwdSpawn( iEntity ) {
    static szClassname[ 32 ];
    entity_get_string( iEntity, EV_SZ_classname, szClassname, 31 );
    
    if( equal( szClassname, info_map_parameters ) ) {
        remove_entity( iEntity );
        
        return FMRES_SUPERCEDE;
    }
    
    return FMRES_IGNORED;
}

public plugin_init( ) {
    if( g_hSpawn > 0 ) {
        unregister_forward( FM_Spawn, g_hSpawn );
    }
}

Properly Removing an Entity at Plugin Start (by Alucard^) - Loại bỏ đúng cách một thực thể tại Plugin Bắt đầu

Code:

#include <amxmodx>
#include <fakemeta>

new const g_RemoveEntity[] = "classname_here";

public plugin_precache()
{
    register_plugin("Fine", "and", "you?");
    
    // Remember to do this in plugin_precache, if you
    // do this in plugin_init( ) this will not work!
    
    register_forward(FM_Spawn, "HookFmSpawn");
}

public HookFmSpawn(iEntity)
{
    if(!pev_valid(iEntity) )
        return FMRES_IGNORED;
    
    static szClassName[32];
    pev(iEntity, pev_classname, szClassName, 31);
    
    if(equali(szClassName, g_RemoveEntity) )
    {
        engfunc(EngFunc_RemoveEntity, iEntity);

        return FMRES_SUPERCEDE;
    }
    
    return FMRES_IGNORED;
}

What is the proper way to respawn someone? - Cách thích hợp để hồi sinh một người nào đó là gì?
Vâng, có hai phương pháp là chính xác và hiệu quả.

Code:

// GOOD, hamsandwich
ExecuteHamB( Ham_CS_RoundRespawn, playerindex )

// GOOD, fakemeta
set_pev( playerindex, pev_deadflag, DEAD_RESPAWNABLE )

// BAD, fun
// This is usable, but requires a fix that really isn't worth it.
spawn( playerindex )

// BAD, cstrike
cs_user_spawn( playerindex )

 Tôi nên sử dụng những Mô-đun gì cho các plugin lớn của tôi? Fakemeta hoặc Engine?
Bạn nên sử dụng bất cứ điều gì mô-đun được công việc làm. Tác động hiệu quả thực tế giữa bao gồm cả hai là rất tầm thường. Đừng do dự để bao gồm cả nếu bạn cần cả hai để có được những gì bạn cần thực hiện đúng.

Tôi đã biên soạn plugin của tôi và cảnh báo thụt đầu dòng lỏng lẻo đã đưa ra. Đây là những gì và làm thế nào tôi có thể sửa chữa nó?
Cảnh báo này xuất hiện bất cứ khi nào bạn thụt dòng của bạn với không gian và các tab. Phù hợp để sử dụng một phong cách; Cá nhân tôi sử dụng các tab vì họ dễ dàng hơn nhiều.

Làm thế nào để tự động thêm vào các giá trị tiêu đề trình đơn của tôi / các mục?

Code:

menufunc()
{
    new info[128]
    formatex( info, 127, "Welcome to the Point Shop^nYour Points: %i", iVariableForPoints[id] )
    new menu = menu_create( info, "HandlerFunction" )
    
    // rest of menu code
}

Nếu bạn có bất kỳ vấn đề mà bạn cảm thấy mọi người quá thường hỏi, xin vui lòng gửi vấn đề / câu hỏi trong một bài hoặc PM và tôi sẽ xem xét việc thêm vào danh sách. Đây là danh sách mà tôi nghĩ ra mà mọi người thường hỏi.